Définir une variable

Synthèse du Jeudi 23-03-2006

 

 

A.  Définition simple d’une variable.

 

1.     Définition.

 

Variable : Emplacement de stockage pouvant contenir un type de données dans le but de les réutiliser pendant l’exécution d’un programme.

 

SET            Affiche, définie ou supprime une variable

                   SET A=Valeur      Définie la variable A

                   SET A=                  Efface la variable A

SET /A      définie une variable au moyen d’une expression numérique

                   SET /A B=2

                   SET /A B=%A%+2

SET /P définie une variable de façon dynamique

 

2.     Exercice.

 

CLS

@echo off

echo Ce programme est une simple calculatrice ne faisant que des multiplications

echo.

PAUSE

 

:Nombre1

CLS

SET /P Nombre1=Entrez un nombre superieur ou egal a 1 :

IF NOT DEFINED Nombre1 GOTO Erreur1

SET /A Verif1=%Nombre1%

IF %Verif1%==0 GOTO Erreur1

:Nombre2

CLS

SET /P Nombre2=Entrez un second nombre superieur ou egal a 1 :

IF NOT DEFINED Nombre2 GOTO Erreur2

SET /A Verif2=%Nombre2%

IF %Verif2%==0 GOTO Erreur2

 

CLS

SET /A Multiplication=%Nombre1%*%Nombre2%

echo %Nombre1%*%Nombre2%=%Multiplication%

echo.

SET Nombre1=

SET Nombre2=

PAUSE

EXIT

 

:Erreur1

echo.

echo Entrer un nombre valide, merci

PAUSE

GOTO Nombre1

:Erreur2

echo.

echo Entrer un nombre valide, merci

PAUSE

GOTO Nombre2

 

B.  Définition complexe d’une variable.

 

1.     Définir une variable avec la sortie d’une commande.

 

SET /P Var=Set Var=< NUL > 1.bat

VER >> 1.bat

CALL 1.bat

SET Var

 

Var=Microsoft Windows XP [version 5.1.2600]

 

2.     Définir une variable avec le contenu d’un fichier texte.

 

echo Bonjour > 1.txt

SET /P Var=Set Var=< NUL > 1.bat

TYPE 1.txt >> 1.bat

CALL 1.bat

SET Var

 

Var=Bonjour

 

3.     Définir une variable avec une partie d’une autre variable.

 

SET A=Sylvestre a mangé Titi

SET B=%A:~-4%

REM Recupere les 4 derniers caracteres de la variable A

SET B

 

B=Titi

 

SET A=Sylvestre a mangé Titi

SET B=%A:~0,9%

REM Recupere 9 caracteres a compter du caractere 0 non compris de la variable A

SET B

 

B=Sylvestre